NES controller to arduino

Couldn't sleep this morning. Instead, i connected a NES controller that was lying around to my Arduino. The NES controller is actually digital, so it only uses three digital pins on the Arduino (plus positive and ground voltage pins) to read the eight button states individually. The code below has been tested and working. This is all thanks to this handy chapter on videogame hardware. Thanks!

I can't think of anything overly useful for this, apart from gutting mechanically defective NES controllers for their 4021 shift registers... but hey, I'm tired. I'm sure there is something cool that can be done with it.

Here is the pinout of the 4021:
P0 to P7 are the parallel digital inputs.
Latch is PL.
Clock is CP.
Serial Out is 07.

Anyway, here are the pinouts of the NES controller (lead plug on controller, not the socket on the console):

The state of the controller is fed out in the following order: A button, B button, select, start, up, down, left, right. Because the code shifts each bit to the left once it has been received, the first bit becomes the most significant bit. The format of the data byte is as follows:

bit 7 = A
bit 6 = B
bit 5 = select
bit 4 = start
bit 3 = up
bit 2 = down
bit 1 = left
bit 0 = right

[expand / collapse code]

/*
Reading a NES Controller
By Sebastian Tomczak
21 July 2007
Adelaide, Australia
*/

/* INITIALISATION */

int latch = 2; // set the latch pin
int clock = 3; // set the clock pin
int datin = 4;// set the data in pin
byte controller_data = 0;

/* SETUP */
void setup() {
Serial.begin(57600);
pinMode(latch,OUTPUT);
pinMode(clock,OUTPUT);
pinMode(datin,INPUT);

digitalWrite(latch,HIGH);
digitalWrite(clock,HIGH);
}

/* CONTROLLER READ */
void controllerRead() {
controller_data = 0;
digitalWrite(latch,LOW);
digitalWrite(clock,LOW);

digitalWrite(latch,HIGH);
delayMicroseconds(2);
digitalWrite(latch,LOW);

controller_data = digitalRead(datin);

for (int i = 1; i <= 7; i ++) {
digitalWrite(clock,HIGH);
delayMicroseconds(2);
controller_data = controller_data << 1;
controller_data = controller_data + digitalRead(datin) ;
delayMicroseconds(4);
digitalWrite(clock,LOW);
}

}

/* PROGRAM */
void loop() {
controllerRead();
Serial.println(controller_data, BIN);
delay(100);
}